symmetricAlgebra(Module) -- the symmetric algebra of a module

Synopsis

Usage:
symmetricAlgebra M
Function: symmetricAlgebra
Inputs:
- M, a module
Outputs:
- a ring, the symmetric algebra of M
Optional inputs:

Description

i1 : R = QQ[a..d];

i2 : M = image matrix{{a,b,c}}

o2 = image | a b c |

                             1
o2 : R-module, submodule of R

i3 : symmetricAlgebra M

     QQ [x , x , x , a, b, c, d, Degrees => {{1, 0}, {1, 0}, {1, 0}, {0, 1}, 
          0   1   2
o3 = ------------------------------------------------------------------------
                                     (x b - x c, x a - x b, x a - x c)
                                       2     1    1     0    2     0
     ------------------------------------------------------------------------
     {0, 1}, {0, 1}, {0, 1}}]

     ------------------------

o3 : QuotientRing

i4 : symmetricAlgebra(R^{1,2,3})

o4 = QQ [x , x , x , a, b, c, d, Degrees => {{1, 0}, {1, 0}, {1, 0}, {0, 1},
          0   1   2
     ------------------------------------------------------------------------
     {0, 1}, {0, 1}, {0, 1}}]

o4 : PolynomialRing

Most of the optional arguments for monoids are available here as well, such as

i5 : symmetricAlgebra(M, Variables=>{x,y,z})

     QQ [x, y, z, a, b, c, d, Degrees => {{1, 0}, {1, 0}, {1, 0}, {0, 1}, {0,
o5 = ------------------------------------------------------------------------
                                   (z*b - y*c, y*a - x*b, z*a - x*c)
     ------------------------------------------------------------------------
      1}, {0, 1}, {0, 1}}]
     ---------------------

o5 : QuotientRing

i6 : symmetricAlgebra(M, VariableBaseName=>G, MonomialSize=>16)

     QQ [G , G , G , G , G , G , G , Degrees => {{1, 0}, {1, 0}, {1, 0}, {0, 
          0   1   2   3   4   5   6
o6 = ------------------------------------------------------------------------
                                              (G G  - G G , G G  - G G , G G 
                                                2 4    1 5   1 3    0 4   2 3
     ------------------------------------------------------------------------
     1}, {0, 1}, {0, 1}, {0, 1}}, MonomialSize => 16]

     ------------------------------------------------
      - G G )
         0 5

o6 : QuotientRing

i7 : symmetricAlgebra(M, Degrees=> {7:1})

        QQ [x , x , x , a, b, c, d]
             0   1   2
o7 = ---------------------------------
     (x b - x c, x a - x b, x a - x c)
       2     1    1     0    2     0

o7 : QuotientRing

Caveat

This function predates the ability to create polynomial rings over polynomial rings, and perhaps that is what should be returned.