# Référence de programmation du &logo; de &kturtle;

Ceci est le manuel de référence du logiciel de programmation &logo; &kturtle;. Dans ce chapitre, nous verrons d'abord brièvement tous les différents types d'instructions. Les commandes seront alors expliquées une par une. Les conteneurs, les mathématiques, les questions et contrôleurs d'exécution seront ensuite expliqués. Enfin, nous vous montrerons comment créer vos propres commandes avec Apprends

## Différents types d'instructions

Comme dans tout langage, le LOGO a différents types de mots et de symboles. Les différences entre les types sont expliquées brièvement ici.

### Commandes

En utilisant les commandes, vous dites à la tortue ou à &kturtle; de faire quelque chose. Certaines commandes ont besoin d'une entrée.

    # avance est une commande qui nécessite une entrée, ici le nombre 100 :
    avance 100

Pour une étude détaillée de toutes les commandes gérées par &kturtle;, allez ici.

### Nombres

Vous savez probablement certaines choses sur les nombres. La façon dont ils sont utilisés dans &kturtle; n'est pas très différente de la façon dont on les utilise dans le langage parlé, ou avec les mathématiques.

Nous avons les nombres appelés nombre naturels : `0`, `1`, `2`, `3`, `4`, `5`, etc. Les nombres négatifs : `-1`, `-2`, `-3`, etc. Enfin les nombres décimaux, où nombres à virgule, par exemple : `0.1`, `3.14`, `33.3333`, `-5.05`, `-1.0`.

Les nombres peuvent être utilisés dans des calculs mathématiques et dans des questions. Ils peuvent également être placés dans des conteneurs.

Les nombres sont colorés en bleu dans l'éditeur de code.

### Chaînes

Tout d'abord un exemple :

    écris "Bonjour, je suis une chaîne."

Dans cet exemple, `écris` est une commande où `Bonjour, je suis une chaîne.` est une chaîne. Les chaînes commencent et se terminent par un symbole `"`. Grâce à ces symboles, &kturtle; sait qu'il s'agit d'une chaîne.

Les chaînes peuvent être placées dans des conteneurs. Cependant, elles ne peuvent pas être utilisées dans des calculs mathématiques ou dans des questions.

Les chaînes sont colorées en rouge sombre dans l'éditeur de code.

### Noms

Lorsque vous programmez en langage &logo;, vous créez de nouvelles choses. Si vous écrivez un programme, vous aurez probablement besoin de conteneurs, et dans certains cas vous aurez à utiliser Apprends pour créer de nouvelles commandes. Lorsque vous faites un conteneur ou une nouvelle commande avec Apprends, vous devez spécifier un nom.

Vous pouvez choisir ce que vous voulez, à partir du moment où ce nom n'a pas déjà une signification. Par exemple, vous ne pouvez pas nommer un conteneur avance puisque ce nom est déjà utilisé pour une commande, et a donc déjà un sens.

    # ici avance est utilisé comme conteneur, mais il a déjà une significtion
    # donc cela produira une erreur :
    avance = 20

    # ceci fonctionne :
    avance 20

Les noms peuvent contenir des lettres, des chiffres et des caractères de soulignement (_). Cependant, ils doivent commencer par une lettre.

Veuillez lire la documentation sur les conteneurs et sur la commande Apprends pour davantage d'explications et d'autres exemples.

### Affectation

Les affectations sont faites avec le symbole `=`. Dans les langages de programmation, il est conseilllé de lire un `=` unique comme « devient » au lieu de « est égal à ». L'expression « est égal à » est plus approprié pour `==` qui est une question.

Les affectations sont généralement utilisées pour deux raisons : (1) pour ajouter du contenu aux conteneurs, et (2) pour modifier le contenu d'un conteneur. Par exemple :

    x = 10
    # le conteneur x contient maintenant le nombre 10
    W = "Mon âge est : "
    # le conteneur W contient maintenant la chaîne "Mon âge est : "
    # ceci affiche le contenu des conteneurs « W » et « x » sur le canevas
    print W + x

Pour d'autres exemples, voyez la section qui traite des conteneurs.

### Symboles mathématiques

&kturtle; gère tous les symboles mathématiques de base : addition (`+`), soustraction (`-`), multiplication (`*`), division (`/`) et les parenthèses (`(` et `)`.

Pour une explication complète et d'autres exemples, voyez la section mathématiques.

### Questions

Nous pouvons poser des questions simples pour lesquelles la réponse sera « vrai » ou « faux ».

L'utilisation des questions est largement décrite dans la section question.

### Mots collants pour questions

Les questions peuvent être collées ensemble avec des « mots collants ». Les mots collants sont `et`, `ou`, et le mot collant spécial `non`.

L'utilisation des mots collants est expliquée dans la section mots collants.

### Commentaires

Les commentaires sont des lignes qui commencent par un `#`. Par exemple :

    # ceci est un commentaire !
    print "ceci n'est pas un commentaire"
    # la ligne précédente n'est pas un commentaire, mais la ligne suivant en est un :
    # print "ceci n'est pas un commentaire"

Vous pouvez ajouter des commentaires dans le code pour vous-même ou pour quelqu'un d'autre. Les commentaires sont utilisés pour : (1) ajouter des descriptions courtes au programme, (2) expliquer comment un morceau de code fonctionne s'il est un eu obscur, et (3) commenter des lignes de code qui doivent être (temporairement) ignorées (voir la dernière ligne de l'exemple).

Les lignes commentées sont colorées en jaune foncé dans l'éditeur de code.

## Commandes

En utilisant les commandes, vous dites à la tortue ou à &kturtle; de faire quelque chose. Certaines commandes ont besoin d'une entrée, d'autres donnent une sortie. Dans ce chapitre nous expliquons toutes les commandes qui peuvent être utilisées dans &kturtle;. Notez que toutes les commandes de base que nous discutons ici sont colorées dans l'éditeur de code. Ceci peut vous aider à les distinguer.

### Déplacer la tortue

Il y a plusieurs commandes qui déplacent la tortue sur l'écran.

#### avance (av)

avance

      avance X

  `avance` fait avancer la tortue sur l'écran de X pixels. Lorsque le crayon est baissé, la tortue laisse une trace (dessine une ligne). `avance` peut se contracter en `av`

#### recule (re)

recule

      recule X

  `recule` fait reculer la tortue sur l'écran de X pixels. Lorsque le crayon est baissé, la tortue laisse une trace (dessine une ligne). `recule` peut se contracter en `re`.

#### tournegauche (tg)

tournegauche

      tournegauche X

  `tournegauche` dit à la tortue de se tourner vers la gauche de X degrés. `tournegauche` peut se contracter en `tg`.

#### tournedroite (td)

tournedroite

      tournedroite X

  `tournedroite` dit à la tortue de se tourner vers la droite de X degrés. `tournedroite` peut se contracter en `td`.

#### direction (dir)

direction

      direction X

  `direction` fixe la direction de la tortue de X degrés en comptant de zéro, et donc ne dépend pas de la position et de la direction précédentes de la tortue. `direction` peut se contracter en `dir`.

#### centre

centre

      centre

  `centre` déplace la tortue au centre du canevas.

#### va

va

      va X,Y

  `va` commande à la tortue d'aller à un certain endroit sur le canevas. Cet endroit est à X pixels depuis la gauche du canevas et à Y pixels depuis le haut du canevas. Veuillez noter qu'en utilisant la commande `va`, la tortue ne va pas dessiner de ligne.

#### vax

vax

      vax X

  `vax` : en utilisant cette commande, la tortue va se déplacer de X pixels depuis la gauche du canevas tandis qu'elle restera à la même hauteur.

#### vay

vay

      vay Y

  `vay` : en utilisant cette commande, la tortue va se déplacer de Y pixels depuis le haut du canevas tandis qu'elle restera à la même distance de la bordure gauche du canevas.

### La tortue a un crayon

La tortue a un crayon qui trace une ligne lorsque la tortue se déplace. Il y a peu de commandes pour contrôler le crayon. Nous expliquons ces commandes dans ce paragraphe.

#### lèvecrayon (lc)

lèvecrayon

      lèvecrayon

  `lèvecrayon` relève le crayon du canevas. Lorsque le crayon est levé, aucune ligne ne sera tracée lorsque la tortue se déplace. Voir aussi `baissecrayon`. `lèvecrayon` peut se contracter en `lc`.

#### baissecrayon (bc)

baissecrayon

      baissecrayon

  `baissecrayon` abaisse le crayon sur le canevas. Lorsque le crayon est baissé sur le canevas, une ligne sera tracée lorsque la tortue se déplace. Voir aussi `lèvecrayon`. `baissecrayon` peut se contracter en `bc`.

#### taillecrayon (ftc)

taillecrayon

      taillecrayon X

  `taillecrayon` fixe l'épaisseur (la largeur du trait) du crayon à X pixels. `taillecrayon` peut se contracter en `ftc`.

#### couleurcrayon (fcc)

couleurcrayon

      couleurcrayon R,G,B

  `couleurcrayon` fixe la couleur du crayon. `couleurcrayon` demande une combinaison RGB comme entrée. `couleurcrayon` peut se contracter en `fcc`.

### Commandes pour contrôler le canevas

Voici les différentes commandes pour contrôler le canevas.

#### taillecanevas (tca)

taillecanevas

      taillecanevas X,Y

  Avec la commande `taillecanevas` vous pouvez fixer la taille du canevas. Elle reçoit X et Y comme entrée, où X est la nouvelle largeur du canevas en pixels, et Y est la nouvelle hauteur du canevas en pixels. `taillecanevas` peut se contracter en `tca`.

#### couleurcanevas (cca)

couleurcanevas

      couleurcanevas R,G,B

  `couleurcanevas` fixe la couleur du canevas. `couleurcanevas` reçoit une combinaison RGB comme entrée. `couleurcanevas` peut se contracter en `cca`.

#### enroule

enroule

      enroule

  Avec la commande `enroule` vous pouvez fixer le bouclage sur on pour le canevas. Veuillez regarder le glossaire pour savoir ce qu'est le bouclage.

#### déroule

déroule

      déroule

  Avec la commande `déroule` vous pouvez fixer le bouclage sur off pour le canevas. Cela signifie que que la tortue peut sortir du canevas et se perdre. Veuillez regarder le glossaire si vous voulez savoir ce qu'est le bouclage.

### Commandes pour nettoyer

Il existe deux commandes pour nettoyer le canevas après avoir mis le désordre.

#### nettoietout (ntt)

nettoietout

      nettoietout

  Avec `nettoietout`, vous pouvez nettoyer tous les dessins sur le canevas. Toutes les autres choses restent : la position et l'angle de la tortue, la couleur du canevas, la visibilité de la tortue et la taille du canevas. `nettoietout` peut se contracter en `ntt`.

#### initialise

initialise

      initialise

  `initialise` nettoie beaucoup plus profondément que la commande `nettoietout`. Après la commande `initialise`, tout redevient comme lorsque vous avez juste lancé &kturtle;. La tortue se place au milieu du canevas, la couleur du canevas est blanche et la couleur du trait de la tortue est noire.

### La tortue est un lutin (sprite)

La plupart des personnes ne savent pas ce qu'un lutin (sprite) est, voici donc une courte explication : les lutins sont de petites images qui peuvent se déplacer sur l'écran. (pour plus d'information, voir le glossaire sur lutins). Donc la tortue est un lutin !

Ce qui suit est un aperçu des commandes relatives aux lutins.

[La version actuelle de &kturtle; ne supporte pas encore l'utilisation des lutins autres que la tortue. Dans des versions futures vous pourrez changer la tortue en quelque chose de votre propre conception ! ]

#### montre

montre (mi)

      montre

  `montre` rend la tortue à nouveau visible après qu'elle ait été cachée. `montre` peut se contracter en `mi`.

#### cache (ci)

cache

      cache

  `cache` cache la tortue. Ceci peut être utilisé si la tortue n'est pas souhaitable sur votre dessin. `cache` peut se contracter en `ci`.

### Est-ce que la tortue peut écrire du texte ?

La réponse est : oui. La tortue peut écrire, elle écrit tout ce que vous lui commander d'écrire.

#### écris

écris

      écris X

  La commande `écris` est utilisée pour commander à la tortue d'écrire quelque chose sur le canevas. `écris` reçoit des nombres et des chaînes de caractères comme entrée. Vous pouvez utiliser `écris` pour imprimer plusieurs nombres et chaînes en utilisant le symbole +. Voici un petit exemple :

      année = 2003
      auteur = "Cies"
      écris "auteur + " a commencé de projet KTurtle en " + année + " et prend toujours du plaisir à travailler dessus ! "

#### taillepolice

taillepolice

      taillepolice X

  `taillepolice` fixe la taille de la police qui est utilisée par la commande `écris`. `taillepolice` reçoit une entrée qui doit être un nombre. La taille est fixée en pixels.

### Une commande qui lance un dé pour vous

Il existe une commande qui lance un dé pour vous, elle s'appelle `hasard`, et est très utile pour des résultats inattendus.

hasard

      hasard X,Y

  `hasard` est une commande qui demande une entrée et qui vous donne une sortie. Comme entrée sont requis deux nombres, le premier (X) donne la sortie minimale, et le second (Y) fixe le maximum. La sortie est un nombre choisi au hasard qui est égal ou plus grand que le minimum et égal ou plus petit que le maximum. Voici un petit exemple :

       répète 500 [
        x = hasard 1,20
        avance x
        tournedroitee 10 - x
      ]

  En utilisant la commande `hasard`, vous pouvez ajouter un peu de chaos dans votre programme.

### Entrée et retour avec les boîtes de dialogue

Une boîte de dialogue est une petite fenêtre surgissante qui fournit du retour ou demande des choses en entrée. &kturtle; possède deux commandes pour les boîtes de dialogue : `message` et `fenêtreentrée`

#### message

message

      message X

  La commande `message` prend une chaîne en entrée. Elle affiche une boîte de dialogue contenant le texte de la chaîne.

      année = 2003
      auteur = "Cies"
      écris "auteur + " a commencé de projet KTurtle en " + année + " et prend toujours du plaisir à travailler dessus ! "

#### fenêtreentrée

fenêtreentrée

      fenêtreentrée X

  `fenêtreentrée` prend une chaîne en entrée. Elle affiche une boîte de dialogue contenant le texte de la chaîne, tout comme la commande message. Mais en plus, elle affiche un champ d'entrée dans la boîte de dialogue. Vous pouvez alors saisir grâce à ce champ un nombre ou une chaîne qui sera stocké dans un conteneur. Par exemple,

      entrée = fenêtreentrée "Quel est votre âge ? "
      sortie = 2005 - entrée
      écris "En 2005, vous aviez " + sortie + " ans."

  Lorsqu'un utilisateur annule la boîte de dialogue, ou ne met rien du tous, le conteneur est vidé.

## Conteneurs

Les conteneurs sont des lettres ou des mots qui peuvent être utilisés par le programmeur pour stocker un nombre ou un texte. Les conteneurs qui contiennent un nombre sont appelés des variables et les conteneurs qui contiennent du texte sont appelés des chaînes.

Les conteneurs qui ne sont pas encore utilisés valent 0 par défaut. Un exemple :

    écris N

Cela n'écrira rien. Si nous essayons de faire des calculs mathématiques avec des conteneurs vides, nous aurons une erreur.

### Variables : conteneurs de nombres

Commençons avec un exemple :

    x = 3
    écris x

À la première ligne, la lettre `x` est utilisée comme une variable (un conteneur de nombres). Comme vous le voyez, la valeur de la variable `x` est fixée sur 3. La deuxième ligne imprime la valeur.

Veuillez noter que si nous avions voulu imprimer un x, nous aurions du écrire

    écris "x"

Ce fut facile, voyons maintenant un exemple plus difficile :

    A = 2004
    B = 25
    AB = A + B

    # la commande suivante imprime "2029"
    écris AB
    recule 30
    # la commande suivante imprime "2004 plus 25"
    écris "" +  A + " plus " + B
    recule 30
    # la commande suivante imprime "1979"
    écris A - B

Dans les deux premières lignes, les variables `A` et `B` sont fixées à 2004 et 25. À la troisième ligne, la variable `AB` est fixée `A + B`, qui vaut 2029. Le reste de l'exemple consiste en trois commandes `écris` avec les `recule 30` entre. Les lignes `recule 30` sont là pour assurer que chaque sortie est imprimée sur une nouvelle ligne. Dans cet exemple, vous voyez aussi que les variables peuventêtre utilisées dans des calculs mathématiques.

### Conteneurs contenant du texte (chaînes)

Dans un programme, le texte commence et se termine généralement par des guillemets. Comme vous l'avez déjà vu :

    écris "Bonjour programmeur ! "

Le texte est délimité par des guillements. Ce texte est appelé une chaîne.

Les chaînes peuvent également être stockées dans des conteneurs, tout comme les nombres. La plus grosse différence est que les chaînes ne peuvent pas être utilisées dans des calculs mathématiques et des questions. Voici un exemple d'utilisation des chaînes :

    x = "Bonjour "
    nom = fenêtreentrée "Veuillez saisir votre nom..."
    écris x + nom + ", comment allez vous ? "

À la première ligne, la variable `x` est fixée à Bonjour . À la deuxième ligne, la chaîne `nom` est fixée sur la sortie de la commande `fenêtreentrée`. À la troisième ligne, le programme imprime une concaténation des trois chaînes sur le canevas.

Ce programme vous demande de saisir votre nom. Lorsque par exemple vous saisissez le nom Paul, le programme imprime Bonjour Paul, comment allez vous ?. Veuillez noter que le signe plus (+) est le seul symbole mathématique que vous pouvez utiliser avec des chaînes.

## Est ce que la tortue peut faire des maths ?

Oui, &kturtle; va aussi faire vos maths. Vous pouvez ajouter (+), soustraire (-), multiplier (*) et diviser (/). Voici un exemple dans lequel nous allons tous les utiliser :

    a = 20 - 5
    b = 15 * 2
    c = 30 / 30
    d = 1 + 1
    écris "a : "+a+", b : "+b+", c : "+c+", d : "+d

Savez vous quelles valeurs ont a, b, c et d ? Notez le symbole d'affectation `=`.

Si vous voulez faire simplement un calcul, vous pouvez le faire de la façon suivante :

    écris 2004-12

Voici maintenant un exemple avec des parenthèses :

    écris ( ( 20 - 5 ) * 2 / 30 ) + 1

Les expressions dans les parenthèses vont être calculées les premières. Dans cet exemple, 20-5 sera calculé, puis multiplié par 2, divisé par 30, puis 1 est ajouté (ce qui donne 2).

## Poser des questions, recevoir des réponses...

`si` et `pendant` sont des contrôleurs d'exécution dont nous allons discuter dans le prochain paragraphe. Dans ce paragraphe nous utilisons la commande `si` pour expliquer les questions.

### Questions

Un simple exemple de question :

    x = 6
    si x > 5 [
      écris "bonjour"
    ]

Dans cet exemple, la question est la partie `x > 5`. Si la réponse à cette question est vraie, le code entre les crochets sera exécuté. Les questions sont une partie importante en programmation et sont souvent utilisées avec des contrôleurs d'exécution, comme `si`. Tous les nombres et variables (conteneurs de nombres) peuvent être comparés les uns aux autres grâce à des questions.

Voici toutes les questions possibles :

#### Types de questions

`a == b` | égal | la réponse est vraie si `a` est égal à `b`
`a != b` | non égal | la réponse est vraie si `a` n'est pas égal à `b`
`a > b` | plus grand que | la réponse est vraie si `a` est plus grand que `b`
`a < b` | plus petit que | la réponse est vraie si `a` est plus petit que `b`
`a >= b` | plus grand ou égal | la réponse est vraie si `a` est plus grand ou égal à `b`
`a <= b` | plus petit ou égal | la réponse est vraie si `a` est plus petit ou égal à `b`

Les questions sont colorées en bleu clair dans l'éditeur de code.

### Mots collants pour questions

Les mots collants pour les questions nous permettent d'assembler plusieurs questions pour n'en former plus qu'une.

    a = 1
    b = 5
    si (a < 5) et (b == 5) [
      écris "bonjour"
    ]

Dans cet exemple, le mot collant `et` est utilisé pour rassembler deux questions (`a < 5`, `b == 5`) ensemble. Si un côté de `et` répondait faux toute la question aurait pour réponse faux, parce qu'avec le mot collant `et` les deux côtés doivent être vrai pour répondre vrai. N'oubliez pas d'utiliser les parenthèses autour des questions !

Voici un aerçu schématique, une explication plus détaillée suit plus bas :

#### Mots collants pour questions

`et` | les deux côtés doivent être vrai pour que la réponse soit vrai
`ou` | si l'un des côtés est vrai la réponse est vrai
`non` | Cas particuliers : ne fonctionne que sur une question ! change « vrai » en « faux » et « faux » en « vrai ».

Les mots collants pour questions sont colorés en violet dans l'éditeur de code.

#### et

Lorsque deux questions sont assemblées avec `et`, les deux côtés du `et` doivent être « vrai » pour que le résultat soit « vrai ». Un exemple :

    a = 1
    b = 5
    si ((a < 10) et (b == 5)) et (a < b) [
      écris "bonjour"
    ]

Dans cet exemple, vous avez deux questions collées, assemblées à une troisième question.

#### ou

Si une des deux questions qui sont assemblées avec `ou` est « vrai », le résultat sera « vrai ». Un exemple :

    a = 1
    b = 5
    si ((a < 10) ou (b == 10)) ou (a == 0) [
      écris "bonjour"
    ]

Dans cet exemple, vous voyez un assemblage de deux questions combiné avec unee troisieme question.

#### non

`non` est un mot-colle spécial car il ne fonctionne qu'avec une question à la fois. `non` change « vrai » en « faux » et « faux » en « vrai ». Un exemple :

    a = 1
    b = 5
    si non ((a < 10à et (b == 5)) [
      écris "bonjour"
    ]
    sinon
    [
      écris "pas bonjour ;-)"
    ]

Dans cet exemple, la question collée est « vrai », pourtant le `non` le change en « faux ». Ainsi, en fin de compte, `"pas bonjour ;-)"` est affiché sur le canevas.

## Contrôler l'exécution

Les contrôleurs d'exécution vous permettent, — comme leur nom l'indique — de contrôler l'exécution.

Les commandes de contrôle d'exécution sont colorées en vert foncé en utilisant une police en gras. Les crochets sont principalement utilisés avec les contrôleurs d'exécution et sont colorés en vert clair.

### Faite attendre la tortue

Si vous avez exécuté quelques programmes dans &kturtle; vous pouvez avoir remarqué que la tortue se déplace très rapidement pour dessiner. La commande suivante ralentit la tortue.

attends

      attends X

  `attends` fait attendre la tortue pendant X secondes.

      répète 36 [
        avance 5
        tournedroite 10
        attends 0.5
      ]

  Ce code dessine un cercle mais la tortue va attendre une demi-seconde après chaque étape. Cela donne l'impression d'une tortue qui va moins vite.

### Exécute "si"

si

      si question [ ... ]

  Le code qui est placé entre les crochets sera exécuté seulement `si` la réponse à la question est vrai. Pour plus d'information, veuillez lire le paragraphe sur les questions dans la page des questions.

      nettoietout
      x = 6
      si x > 5 [
        écris "x est plus grand que cinq ! "
      ]

  À la première ligne, `x` est fixé à 6. À la seconde ligne, la question `x > 5` est posée. Comme la réponse à la question est vraie, le contrôleur d'exécution `si` va permettre au code entre crochets d'être exécuté.

### La boucle "pendant"

pendant

      pendant question [ ... ]

  Le contrôleur d'exécution `pendant` ressemble beaucoup à `si`. La différence est que `pendant` répète le code entre crochets jusqu'à ce que la réponse à la question soit faux.

      x = 1
      pendant x < 5 [
        avance 10
        attends 1
        x = x + 1
      ]

  À la première ligne, `x` est fixé à 1. À la seconde ligne, la question `x < 5` est posée. Comme la réponse à cette question est vraie, le contrôleur d'exécution `pendant` commence à exécuter le code entre les crochets jusqu'à ce que la réponse à la question soit faux. Dans ce cas, le code entre les crochets sera exécuté 4 fois, à chaque fois que la cinquième ligne est exécutée, `x` augmente de 1.

### Si non, en d'autres mots : "sinon"

sinon

      si question [ ... ] sinon [ ... ]

  `sinon` peut être utilisé en plus du contrôleur d'exécution `si`. Le code entre les crochets après `sinon` n'est exécuté que si la réponse à la question qui est posée est fausse.

      initialise
      x = 4
      si x > 5 [
        écris "x est plus grand que cinq ! "
      ] sinon [
        écris "x est plus petit que six ! "
      ]

  La question demande si `x` est plus grand que 5. Comme `x` est fixé à 4 à la première ligne, la réponse à la question est fausse. Cela signifie que le code entre les crochets après `sinon` est exécuté.

### La boucle "pour", une boucle de comptage

pour

      pour point de départ à point d'arrivée [ ... ]

  La boucle `pour` est une boucle de comptage, par exemple elle garde le compte pour vous.

      pour x = 1 à 10 [
        écris x * 7
        avance 15
      ]

  Chaque fois que le code entre crochets est exécuté, la valeur de `x` augmente de 1, jusqu'à ce que `x` atteigne la valeur 10. Le code entre les parenthèses écrit `x` multiplié par 7. Après que ce programme ait fini son exécution, vous allez voir la table de multiplication de 7 imprimée sur le canevas.

## Créez vos propres commandes !

`apprends` est une commande très spéciale, car elle est utilisée pour créer vos propres commandes. La commande que vous créez peut recevoir des entrées et retourner des sorties. Regardons maintenant comment une nouvelle commande est créée :

    apprends cercle (x) [
      répète 36 [
        avance x
        tournegauche 10
      ]
    ]

La nouvelle commande est appelée `cercle`. `cercle` reçoit une entrée, un nombre, qui fixe la taille du cercle. `cercle` ne retourne aucune sortie. La commande `cercle` peut maintenant être utilisée comme une commande normale dans la suite du programme. Voyez cet exemple :

    apprends cercle X [
      répète 36 [
        avance X
        tournegauche 10
      ]
    ]

    va 30,30
    cercle 20

    va 40,40
    cercle 50

Dans l'exemple suivant, une commande avec une valeur de retour est créée.

    apprends multiplierParSoi (n) [
      r = n * n
      retourne r
    ]
    i = fenêtreentrée "Veuillez saisir un nombre et appuyer sur OK"
    écris i + " multiplié par lui-même est : " + multiplierParSoi (i)

Dans cet exemple, une nouvelle commande appelée `multiplierParSoi` est créée. L'entrée de cette commande est multipliée par elle-même puis retournée, en utilisant la commande `retourne`. La commande `retourne` est le seul moyen de sortir une valeur de la fonction que vous avez créée.